project_6/cccl_upstream/thrust/examples/mode.cu

#include <thrust/device_vector.h>
#include <thrust/extrema.h>
#include <thrust/functional.h>
#include <thrust/host_vector.h>
#include <thrust/iterator/zip_iterator.h>
#include <thrust/random.h>
#include <thrust/reduce.h>
#include <thrust/sort.h>
#include <thrust/unique.h>

#include <cuda/iterator>

#include <iostream>
#include <iterator>

// This example compute the mode [1] of a set of numbers.  If there
// are multiple modes, one with the smallest value it returned.
//
// [1] http://en.wikipedia.org/wiki/Mode_(statistics)

int main()
{
  const size_t N = 30;
  const size_t M = 10;
  thrust::default_random_engine rng;
  thrust::uniform_int_distribution<int> dist(0, M - 1);

  // generate random data on the host
  thrust::host_vector<int> h_data(N);
  for (auto& e : h_data)
  {
    e = dist(rng);
  }

  // transfer data to device
  thrust::device_vector<int> d_data(h_data);

  // print the initial data
  std::cout << "initial data" << '\n';
  thrust::copy(d_data.begin(), d_data.end(), std::ostream_iterator<int>(std::cout, " "));
  std::cout << '\n';

  // sort data to bring equal elements together
  thrust::sort(d_data.begin(), d_data.end());

  // print the sorted data
  std::cout << "sorted data" << '\n';
  thrust::copy(d_data.begin(), d_data.end(), std::ostream_iterator<int>(std::cout, " "));
  std::cout << '\n';

  // count number of unique keys
  size_t num_unique = thrust::unique_count(d_data.begin(), d_data.end());

  // count multiplicity of each key
  thrust::device_vector<int> d_output_keys(num_unique);
  thrust::device_vector<int> d_output_counts(num_unique);
  thrust::reduce_by_key(
    d_data.begin(), d_data.end(), cuda::constant_iterator<int>(1), d_output_keys.begin(), d_output_counts.begin());

  // print the counts
  std::cout << "values" << '\n';
  thrust::copy(d_output_keys.begin(), d_output_keys.end(), std::ostream_iterator<int>(std::cout, " "));
  std::cout << '\n';

  // print the counts
  std::cout << "counts" << '\n';
  thrust::copy(d_output_counts.begin(), d_output_counts.end(), std::ostream_iterator<int>(std::cout, " "));
  std::cout << '\n';

  // find the index of the maximum count
  thrust::device_vector<int>::iterator mode_iter;
  mode_iter = thrust::max_element(d_output_counts.begin(), d_output_counts.end());

  int mode        = d_output_keys[cuda::std::distance(d_output_counts.begin(), mode_iter)];
  int occurrences = *mode_iter;

  std::cout << "Modal value " << mode << " occurs " << occurrences << " times " << '\n';

  return 0;
}