56fd68e7dd
CCCL (CUDA C++ Core Libraries) provides: - CUB: device/block/warp-level GPU primitives (reduce, scan, sort, topk) - Thrust: high-level parallel algorithms (transform_reduce, sort, scan) - libcudacxx: CUDA C++ standard library (atomics, barriers, memory) - cudax: experimental features (memory resources, allocators) - Tuning policies: per-SM hardware-specific algorithm parameters Competition optimization vectors mapped to CCCL: - Output TPS (83% weight): warp_reduce, block_reduce, device_topk - Input TPS (14% weight): device_scan, block_load, prefetch - Cache TPS (3% weight): prefix caching strategy patterns - Memory (0.9 util): pooled/cached/buddy allocators Source: https://github.com/NVIDIA/cccl (shallow clone, HEAD only) License: Apache-2.0
54 lines
2.2 KiB
CMake
54 lines
2.2 KiB
CMake
# SPDX-FileCopyrightText: Copyright (c) 2023 NVIDIA CORPORATION & AFFILIATES. All rights reserved.
|
|
# SPDX-License-Identifier: Apache-2.0
|
|
#
|
|
# Licensed under the Apache License, Version 2.0 (the "License");
|
|
# you may not use this file except in compliance with the License.
|
|
# You may obtain a copy of the License at
|
|
#
|
|
# http://www.apache.org/licenses/LICENSE-2.0
|
|
#
|
|
# Unless required by applicable law or agreed to in writing, software
|
|
# distributed under the License is distributed on an "AS IS" BASIS,
|
|
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
# See the License for the specific language governing permissions and
|
|
# limitations under the License.
|
|
|
|
cmake_minimum_required(VERSION 3.18 FATAL_ERROR)
|
|
|
|
project(CCCLDemo CUDA)
|
|
|
|
# This example uses the CMake Package Manager (CPM) to simplify fetching CCCL from GitHub
|
|
# For more information, see https://github.com/cpm-cmake/CPM.cmake
|
|
include(cmake/CPM.cmake)
|
|
|
|
# We define these as variables so they can be overridden in CI to pull from a PR instead of CCCL `main`
|
|
# In your project, these variables are unnecessary and you can just use the values directly
|
|
set(
|
|
CCCL_REPOSITORY
|
|
"https://github.com/NVIDIA/cccl"
|
|
CACHE STRING
|
|
"Git repository to fetch CCCL from"
|
|
)
|
|
set(CCCL_TAG "main" CACHE STRING "Git tag/branch to fetch from CCCL repository")
|
|
|
|
# This will automatically clone CCCL from GitHub and make the exported cmake targets available
|
|
CPMAddPackage(NAME CCCL GIT_REPOSITORY "${CCCL_REPOSITORY}" GIT_TAG ${CCCL_TAG})
|
|
|
|
# Default to building for the GPU on the current system
|
|
if (NOT DEFINED CMAKE_CUDA_ARCHITECTURES)
|
|
set(CMAKE_CUDA_ARCHITECTURES native)
|
|
endif()
|
|
|
|
# Creates a cmake executable target for the main program
|
|
add_executable(example_project example.cu)
|
|
target_compile_features(example_project PUBLIC cuda_std_17)
|
|
|
|
# "Links" the CCCL Cmake target to the `example_project` executable. This configures everything needed to use
|
|
# CCCL headers, including setting up include paths, compiler flags, etc.
|
|
target_link_libraries(example_project PRIVATE CCCL::CCCL)
|
|
|
|
# This is only relevant for internal testing and not needed by end users.
|
|
include(CTest)
|
|
enable_testing()
|
|
add_test(NAME example_project COMMAND example_project)
|