56fd68e7dd
CCCL (CUDA C++ Core Libraries) provides: - CUB: device/block/warp-level GPU primitives (reduce, scan, sort, topk) - Thrust: high-level parallel algorithms (transform_reduce, sort, scan) - libcudacxx: CUDA C++ standard library (atomics, barriers, memory) - cudax: experimental features (memory resources, allocators) - Tuning policies: per-SM hardware-specific algorithm parameters Competition optimization vectors mapped to CCCL: - Output TPS (83% weight): warp_reduce, block_reduce, device_topk - Input TPS (14% weight): device_scan, block_load, prefetch - Cache TPS (3% weight): prefix caching strategy patterns - Memory (0.9 util): pooled/cached/buddy allocators Source: https://github.com/NVIDIA/cccl (shallow clone, HEAD only) License: Apache-2.0
61 lines
1.8 KiB
CMake
61 lines
1.8 KiB
CMake
# Given a cu_file (e.g. foo/bar.cu) relative to CMAKE_CURRENT_SOURCE_DIR
|
|
# and a thrust_target, create a cpp file that includes the .cu file, and set
|
|
# ${cpp_file_var} in the parent scope to the full path of the new file. The new
|
|
# file will be generated in:
|
|
# ${CMAKE_CURRENT_BINARY_DIR}/<thrust_target_prefix>/${cu_file}.cpp
|
|
function(thrust_wrap_cu_in_cpp cpp_file_var cu_file thrust_target)
|
|
thrust_get_target_property(prefix ${thrust_target} PREFIX)
|
|
set(wrapped_source_file "${CMAKE_CURRENT_SOURCE_DIR}/${cu_file}")
|
|
set(cpp_file "${CMAKE_CURRENT_BINARY_DIR}/${prefix}/${cu_file}.cpp")
|
|
configure_file(
|
|
"${Thrust_SOURCE_DIR}/cmake/wrap_source_file.cpp.in"
|
|
"${cpp_file}"
|
|
)
|
|
set(${cpp_file_var} "${cpp_file}" PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
# thrust_configure_cuda_target(<target_name> RDC <ON|OFF>)
|
|
#
|
|
# Configures `target_name` with the appropriate CUDA architectures and RDC state.
|
|
function(thrust_configure_cuda_target target_name)
|
|
set(options)
|
|
set(one_value_args RDC)
|
|
set(multi_value_args)
|
|
cmake_parse_arguments(
|
|
thrust_cuda
|
|
"${options}"
|
|
"${one_value_args}"
|
|
"${multi_value_args}"
|
|
${ARGN}
|
|
)
|
|
|
|
if (thrust_cuda_UNPARSED_ARGUMENTS)
|
|
message(
|
|
AUTHOR_WARNING
|
|
"Unrecognized arguments passed to thrust_configure_cuda_target: "
|
|
${thrust_cuda_UNPARSED_ARGUMENTS}
|
|
)
|
|
endif()
|
|
|
|
if (NOT DEFINED thrust_cuda_RDC)
|
|
message(
|
|
AUTHOR_WARNING
|
|
"RDC option required for thrust_configure_cuda_target."
|
|
)
|
|
endif()
|
|
|
|
if (thrust_cuda_RDC)
|
|
set_target_properties(
|
|
${target_name}
|
|
PROPERTIES #
|
|
CUDA_SEPARABLE_COMPILATION ON
|
|
POSITION_INDEPENDENT_CODE ON
|
|
)
|
|
else()
|
|
set_target_properties(
|
|
${target_name}
|
|
PROPERTIES CUDA_SEPARABLE_COMPILATION OFF
|
|
)
|
|
endif()
|
|
endfunction()
|