2a7ca101d7
Sparse-checkout from NVIDIA/cccl main branch to complete cccl_upstream: Added: - python/cuda_cccl/ (226 files) — Python bindings for device-level algorithms Critical for muh toolchain: cuda.compute.reduce_into, scan, radix_sort, etc. Includes 204 .py files with full test coverage for all 27 algorithms - ci/ (163 files) — Build/test infrastructure build_cub.sh, test_cub.sh, build_and_test_targets.sh, matrix.yaml Directly maps to our [INFRA-CI] and [INFRA-BUILD] items - .agent/skills/ (7 files) — NVIDIA's own agent skills for CCCL cccl-style/SKILL.md, cccl-test/SKILL.md, sass-diff/SKILL.md - docs/ (491 files) — Official CCCL documentation CI references, CMake guides, Python compute docs, libcudacxx PTX docs - test/ (12 files) — Top-level integration tests (cuda_smoke, stdpar) - Root configs: .clang-format, .clang-tidy, CONTRIBUTING.md, pyproject.toml - CLAUDE.md symlink → AGENTS.md (NVIDIA's standard) cccl_upstream now mirrors full NVIDIA/cccl structure: Before: 42M (cub + thrust + libcudacxx + cudax + c + examples + benchmarks) After: 53M (+python +ci +docs +.agent +test +configs) This completes the CCCL base needed for: - [muh-bench] items: ci/util/build_and_test_targets.sh for targeted builds - [CCCL-verify] items: python/cuda_cccl/tests/ as reference implementations - [CCCL-test] items: ci/test_cub.sh, ci/test_thrust.sh - Agent workflow: .agent/skills/ for consistent style and test patterns
55 lines
1.5 KiB
CMake
55 lines
1.5 KiB
CMake
cmake_minimum_required(VERSION 3.21)
|
|
|
|
# NOTE: this is build outside of the libcu++ test harness
|
|
project(CCCL_STDPAR_TESTS LANGUAGES CXX)
|
|
|
|
if (NOT CMAKE_CXX_COMPILER_ID STREQUAL NVHPC)
|
|
message(FATAL_ERROR "The stdpar tests require nvc++ for CMAKE_CXX_COMPILER.")
|
|
endif()
|
|
|
|
# Enable testing for the project
|
|
enable_testing()
|
|
|
|
find_package(
|
|
CCCL
|
|
CONFIG
|
|
REQUIRED
|
|
NO_DEFAULT_PATH # Only check the explicit HINTS below:
|
|
HINTS "${CMAKE_CURRENT_LIST_DIR}/../../lib/cmake/cccl/"
|
|
)
|
|
|
|
file(
|
|
GLOB test_files
|
|
LIST_DIRECTORIES false
|
|
RELATIVE "${CMAKE_CURRENT_LIST_DIR}"
|
|
CONFIGURE_DEPENDS
|
|
"tests/*.cpp"
|
|
)
|
|
|
|
function(cccl_add_stdpar_test test_file)
|
|
get_filename_component(test_name ${test_file} NAME_WE)
|
|
|
|
add_executable(stdpar_test_${test_name} ${test_file})
|
|
target_link_libraries(stdpar_test_${test_name} PUBLIC CCCL::CCCL)
|
|
|
|
# Ensure that we are testing with GPU support
|
|
target_compile_options(stdpar_test_${test_name} PUBLIC -stdpar=gpu)
|
|
target_link_options(stdpar_test_${test_name} PUBLIC -stdpar=gpu)
|
|
|
|
# Ensure that we are indeed testing the same CCCL version
|
|
target_compile_definitions(
|
|
stdpar_test_${test_name}
|
|
PUBLIC
|
|
CMAKE_CCCL_VERSION_MAJOR=${CCCL_VERSION_MAJOR}
|
|
CMAKE_CCCL_VERSION_MINOR=${CCCL_VERSION_MINOR}
|
|
CMAKE_CCCL_VERSION_PATCH=${CCCL_VERSION_PATCH}
|
|
)
|
|
|
|
# Register with ctest
|
|
add_test(NAME stdpar_test_${test_name} COMMAND stdpar_test_${test_name})
|
|
endfunction()
|
|
|
|
foreach (test IN LISTS test_files)
|
|
cccl_add_stdpar_test(${test})
|
|
endforeach()
|