dedf08166a
Added 863 files from NVIDIA/cccl sparse checkout: - c2h/ (27 files): Catch2 test helpers — generators, validators, runner - nvbench_helper/ (10 files): Benchmark harness utilities - cmake/ (29 files): CMake presets and build helpers - cudax/ (794 files): Experimental CUDA extensions - AGENTS.md: NVIDIA's official AI agent instructions for CCCL - CMakePresets.json: Standardized build configurations - cccl-version.json: Version tracking Also added CCCL_ASSET_MAP.md mapping all 4295 CCCL files to competition value and PRD items. cccl_upstream now covers 100% of competition-critical assets: - 27 tuning headers (SM80/90/100 benchmark data) - 32 dispatch headers (algorithm implementations) - 60 Thrust examples (correctness verification) - 217 CUB Catch2 tests (regression matrix) - 153 CUB benchmarks (parameter space search) - 18 CUB examples (API verification) - 27 test helpers + benchmark harness - 794 cudax experimental extensions
96 lines
2.5 KiB
Plaintext
96 lines
2.5 KiB
Plaintext
//===----------------------------------------------------------------------===//
|
|
//
|
|
// Part of CUDASTF in CUDA C++ Core Libraries,
|
|
// under the Apache License v2.0 with LLVM Exceptions.
|
|
// See https://llvm.org/LICENSE.txt for license information.
|
|
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
|
// SPDX-FileCopyrightText: Copyright (c) 2022-2024 NVIDIA CORPORATION & AFFILIATES.
|
|
//
|
|
//===----------------------------------------------------------------------===//
|
|
|
|
/**
|
|
* @file
|
|
*
|
|
* @brief Jacobi method with parallel_for
|
|
*
|
|
*/
|
|
|
|
#include <cuda/experimental/stf.cuh>
|
|
|
|
#include <iostream>
|
|
|
|
using namespace cuda::experimental::stf;
|
|
|
|
int main(int argc, char** argv)
|
|
{
|
|
context ctx;
|
|
|
|
size_t n = 4096;
|
|
size_t m = 4096;
|
|
double tol = 0.5;
|
|
size_t iter_max = 1000;
|
|
|
|
if (argc > 2)
|
|
{
|
|
n = atol(argv[1]);
|
|
m = atol(argv[2]);
|
|
}
|
|
|
|
if (argc > 3)
|
|
{
|
|
tol = atof(argv[3]);
|
|
}
|
|
|
|
if (argc > 4)
|
|
{
|
|
iter_max = atoi(argv[4]);
|
|
}
|
|
|
|
auto lA = ctx.logical_data(shape_of<slice<double, 2>>(m, n));
|
|
auto lAnew = ctx.logical_data(lA.shape());
|
|
|
|
ctx.parallel_for(lA.shape(), lA.write(), lAnew.write()).set_symbol("init")->*
|
|
[=] __device__(size_t i, size_t j, auto A, auto Anew) {
|
|
A(i, j) = (i == j) ? 10.0 : -1.0;
|
|
Anew(i, j) = A(i, j);
|
|
};
|
|
|
|
cudaEvent_t start, stop;
|
|
|
|
cuda_safe_call(cudaEventCreate(&start));
|
|
cuda_safe_call(cudaEventCreate(&stop));
|
|
|
|
cuda_safe_call(cudaEventRecord(start, ctx.fence()));
|
|
|
|
auto lresidual = ctx.logical_data(shape_of<scalar_view<double>>());
|
|
|
|
size_t iter = 0;
|
|
do
|
|
{
|
|
ctx.parallel_for(inner<1>(lA.shape()), lA.read(), lAnew.rw(), lresidual.reduce(reducer::maxval<double>{}))
|
|
->*[] __device__(size_t i, size_t j, auto A, auto Anew, auto& residual) {
|
|
Anew(i, j) = 0.25 * (A(i - 1, j) + A(i + 1, j) + A(i, j - 1) + A(i, j + 1));
|
|
residual = ::std::max(residual, fabs(A(i, j) - Anew(i, j)));
|
|
};
|
|
|
|
ctx.parallel_for(inner<1>(lA.shape()), lA.rw(), lAnew.read())->*[] __device__(size_t i, size_t j, auto A, auto Anew) {
|
|
A(i, j) = Anew(i, j);
|
|
};
|
|
|
|
iter++;
|
|
|
|
} while (ctx.wait(lresidual) > tol && iter < iter_max);
|
|
|
|
cuda_safe_call(cudaEventRecord(stop, ctx.fence()));
|
|
|
|
double final_residual = ctx.wait(lresidual);
|
|
|
|
printf("Converged after %ld iterations, residual = %lf\n", iter, final_residual);
|
|
|
|
ctx.finalize();
|
|
|
|
float elapsedTime;
|
|
cudaEventElapsedTime(&elapsedTime, start, stop);
|
|
printf("Elapsed time: %f ms\n", elapsedTime);
|
|
}
|