dedf08166a
Added 863 files from NVIDIA/cccl sparse checkout: - c2h/ (27 files): Catch2 test helpers — generators, validators, runner - nvbench_helper/ (10 files): Benchmark harness utilities - cmake/ (29 files): CMake presets and build helpers - cudax/ (794 files): Experimental CUDA extensions - AGENTS.md: NVIDIA's official AI agent instructions for CCCL - CMakePresets.json: Standardized build configurations - cccl-version.json: Version tracking Also added CCCL_ASSET_MAP.md mapping all 4295 CCCL files to competition value and PRD items. cccl_upstream now covers 100% of competition-critical assets: - 27 tuning headers (SM80/90/100 benchmark data) - 32 dispatch headers (algorithm implementations) - 60 Thrust examples (correctness verification) - 217 CUB Catch2 tests (regression matrix) - 153 CUB benchmarks (parameter space search) - 18 CUB examples (API verification) - 27 test helpers + benchmark harness - 794 cudax experimental extensions
83 lines
2.4 KiB
Plaintext
83 lines
2.4 KiB
Plaintext
//===----------------------------------------------------------------------===//
|
|
//
|
|
// Part of CUDA Experimental in CUDA C++ Core Libraries,
|
|
// under the Apache License v2.0 with LLVM Exceptions.
|
|
// See https://llvm.org/LICENSE.txt for license information.
|
|
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
|
// SPDX-FileCopyrightText: Copyright (c) 2024 NVIDIA CORPORATION & AFFILIATES.
|
|
//
|
|
//===----------------------------------------------------------------------===//
|
|
|
|
#include <cuda/experimental/execution.cuh>
|
|
|
|
#include <nv/target>
|
|
|
|
#include <cstdio>
|
|
|
|
#include <cuda_runtime_api.h>
|
|
|
|
namespace cudax = cuda::experimental;
|
|
namespace ex = cudax::execution;
|
|
|
|
// This example demonstrates how to use the experimental CUDA implementation of
|
|
// C++26's std::execution async tasking framework.
|
|
|
|
int main()
|
|
{
|
|
try
|
|
{
|
|
auto tctx = ex::thread_context{};
|
|
auto sctx = ex::stream_context{cuda::device_ref{0}};
|
|
auto gpu = sctx.get_scheduler();
|
|
|
|
const auto bulk_shape = 10;
|
|
const auto bulk_fn = [] __device__(const int index, int i) noexcept {
|
|
const int tid = static_cast<int>(blockIdx.x * blockDim.x + threadIdx.x);
|
|
if (tid < bulk_shape)
|
|
{
|
|
printf("Hello from bulk task on device! index = %d, i = %d\n", index, i);
|
|
}
|
|
};
|
|
|
|
auto start =
|
|
// begin work on the GPU:
|
|
ex::schedule(gpu)
|
|
|
|
// execute a device lambda on the GPU:
|
|
| ex::then([] __device__() noexcept -> int {
|
|
printf("Hello from lambda on device!\n");
|
|
return 42;
|
|
})
|
|
|
|
// do some parallel work on the GPU:
|
|
| ex::bulk(ex::par, bulk_shape, bulk_fn) //
|
|
|
|
// transfer execution back to the CPU:
|
|
| ex::continues_on(tctx.get_scheduler())
|
|
|
|
// execute a host/device lambda on the CPU:
|
|
| ex::then([] __host__ __device__(int i) noexcept -> int {
|
|
NV_IF_ELSE_TARGET(NV_IS_HOST,
|
|
(printf("Hello from lambda on host! i = %d\n", i);),
|
|
(printf("OOPS! still on the device! i = %d\n", i);))
|
|
return i + 1;
|
|
});
|
|
|
|
// run the task, wait for it to finish, and get the result
|
|
auto [i] = ex::sync_wait(std::move(start)).value();
|
|
printf("All done on the host! result = %d\n", i);
|
|
}
|
|
catch (cuda::cuda_error const& e)
|
|
{
|
|
std::printf("CUDA error: %s\n", e.what());
|
|
}
|
|
catch (std::exception const& e)
|
|
{
|
|
std::printf("Exception: %s\n", e.what());
|
|
}
|
|
catch (...)
|
|
{
|
|
std::printf("Unknown exception\n");
|
|
}
|
|
}
|