dedf08166a
Added 863 files from NVIDIA/cccl sparse checkout: - c2h/ (27 files): Catch2 test helpers — generators, validators, runner - nvbench_helper/ (10 files): Benchmark harness utilities - cmake/ (29 files): CMake presets and build helpers - cudax/ (794 files): Experimental CUDA extensions - AGENTS.md: NVIDIA's official AI agent instructions for CCCL - CMakePresets.json: Standardized build configurations - cccl-version.json: Version tracking Also added CCCL_ASSET_MAP.md mapping all 4295 CCCL files to competition value and PRD items. cccl_upstream now covers 100% of competition-critical assets: - 27 tuning headers (SM80/90/100 benchmark data) - 32 dispatch headers (algorithm implementations) - 60 Thrust examples (correctness verification) - 217 CUB Catch2 tests (regression matrix) - 153 CUB benchmarks (parameter space search) - 18 CUB examples (API verification) - 27 test helpers + benchmark harness - 794 cudax experimental extensions
59 lines
1.2 KiB
CMake
59 lines
1.2 KiB
CMake
# Configures a target for the STF framework.
|
|
function(cudax_stf_configure_target target_name)
|
|
set(options LINK_MATHLIBS)
|
|
set(oneValueArgs)
|
|
set(multiValueArgs)
|
|
cmake_parse_arguments(
|
|
CSCT
|
|
"${options}"
|
|
"${oneValueArgs}"
|
|
"${multiValueArgs}"
|
|
${ARGN}
|
|
)
|
|
|
|
target_link_libraries(
|
|
${target_name}
|
|
PRIVATE #
|
|
CUDA::cudart_static
|
|
CUDA::curand
|
|
CUDA::cuda_driver
|
|
)
|
|
|
|
if (cudax_ENABLE_CUDASTF_CODE_GENERATION)
|
|
target_compile_options(
|
|
${target_name}
|
|
PRIVATE $<$<COMPILE_LANG_AND_ID:CUDA,NVIDIA>:--extended-lambda>
|
|
)
|
|
else()
|
|
target_compile_definitions(
|
|
${target_name}
|
|
PRIVATE "CUDASTF_DISABLE_CODE_GENERATION"
|
|
)
|
|
endif()
|
|
|
|
target_compile_options(
|
|
${target_name}
|
|
PRIVATE $<$<COMPILE_LANG_AND_ID:CUDA,NVIDIA>:--expt-relaxed-constexpr>
|
|
)
|
|
|
|
set_target_properties(
|
|
${target_name}
|
|
PROPERTIES #
|
|
CUDA_RUNTIME_LIBRARY Static
|
|
CUDA_SEPARABLE_COMPILATION ON
|
|
)
|
|
|
|
if (CSCT_LINK_MATHLIBS)
|
|
target_link_libraries(
|
|
${target_name}
|
|
PRIVATE #
|
|
CUDA::cublas
|
|
CUDA::cusolver
|
|
)
|
|
endif()
|
|
|
|
if (cudax_ENABLE_CUDASTF_BOUNDSCHECK)
|
|
target_compile_definitions(${target_name} PRIVATE "CUDASTF_BOUNDSCHECK")
|
|
endif()
|
|
endfunction()
|