dedf08166a
Added 863 files from NVIDIA/cccl sparse checkout: - c2h/ (27 files): Catch2 test helpers — generators, validators, runner - nvbench_helper/ (10 files): Benchmark harness utilities - cmake/ (29 files): CMake presets and build helpers - cudax/ (794 files): Experimental CUDA extensions - AGENTS.md: NVIDIA's official AI agent instructions for CCCL - CMakePresets.json: Standardized build configurations - cccl-version.json: Version tracking Also added CCCL_ASSET_MAP.md mapping all 4295 CCCL files to competition value and PRD items. cccl_upstream now covers 100% of competition-critical assets: - 27 tuning headers (SM80/90/100 benchmark data) - 32 dispatch headers (algorithm implementations) - 60 Thrust examples (correctness verification) - 217 CUB Catch2 tests (regression matrix) - 153 CUB benchmarks (parameter space search) - 18 CUB examples (API verification) - 27 test helpers + benchmark harness - 794 cudax experimental extensions
70 lines
2.0 KiB
CMake
70 lines
2.0 KiB
CMake
include(${CMAKE_SOURCE_DIR}/benchmarks/cmake/CCCLBenchmarkRegistry.cmake)
|
|
|
|
cccl_get_nvbench()
|
|
cccl_get_nvbench_helper()
|
|
|
|
set(benches_root "${CMAKE_CURRENT_LIST_DIR}")
|
|
|
|
function(get_recursive_subdirs subdirs)
|
|
set(dirs)
|
|
file(
|
|
GLOB_RECURSE contents
|
|
CONFIGURE_DEPENDS
|
|
LIST_DIRECTORIES ON
|
|
"${CMAKE_CURRENT_LIST_DIR}/bench/*"
|
|
)
|
|
|
|
foreach (bench_dir IN LISTS contents)
|
|
if (IS_DIRECTORY "${bench_dir}")
|
|
list(APPEND dirs "${bench_dir}")
|
|
endif()
|
|
endforeach()
|
|
|
|
set(${subdirs} "${dirs}" PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
function(add_bench target_name bench_name bench_src)
|
|
set(bench_target ${bench_name})
|
|
set(${target_name} ${bench_target} PARENT_SCOPE)
|
|
|
|
cccl_add_executable(${bench_target} SOURCES "${bench_src}")
|
|
target_link_libraries(
|
|
${bench_target}
|
|
PRIVATE #
|
|
cccl.nvbench_helper
|
|
nvbench::main
|
|
)
|
|
endfunction()
|
|
|
|
function(add_bench_dir bench_dir)
|
|
file(GLOB bench_srcs CONFIGURE_DEPENDS "${bench_dir}/*.cu")
|
|
file(RELATIVE_PATH bench_prefix "${benches_root}" "${bench_dir}")
|
|
file(TO_CMAKE_PATH "${bench_prefix}" bench_prefix)
|
|
string(REPLACE "/" "." bench_prefix "${bench_prefix}")
|
|
|
|
foreach (bench_src IN LISTS bench_srcs)
|
|
get_filename_component(bench_name "${bench_src}" NAME_WLE)
|
|
string(PREPEND bench_name "cudax.${bench_prefix}.")
|
|
register_cccl_benchmark("${bench_name}" "")
|
|
|
|
string(APPEND bench_name ".base")
|
|
|
|
add_bench(base_bench_target ${bench_name} "${bench_src}")
|
|
target_link_libraries(${bench_name} PRIVATE cudax.compiler_interface)
|
|
target_compile_options(
|
|
${bench_name}
|
|
PRIVATE
|
|
"$<$<COMPILE_LANG_AND_ID:CUDA,NVIDIA>:--extended-lambda>"
|
|
# cudax.compiler_interface enables assertions for tests/examples; benchmarks should measure release behavior.
|
|
"$<$<COMPILE_LANGUAGE:CUDA>:-UCCCL_ENABLE_ASSERTIONS>"
|
|
"$<$<COMPILE_LANGUAGE:CXX>:-UCCCL_ENABLE_ASSERTIONS>"
|
|
)
|
|
endforeach()
|
|
endfunction()
|
|
|
|
get_recursive_subdirs(subdirs)
|
|
|
|
foreach (subdir IN LISTS subdirs)
|
|
add_bench_dir("${subdir}")
|
|
endforeach()
|