[CCCL] Add missing CCCL components: c2h, nvbench_helper, cmake, cudax, AGENTS.md
Added 863 files from NVIDIA/cccl sparse checkout: - c2h/ (27 files): Catch2 test helpers — generators, validators, runner - nvbench_helper/ (10 files): Benchmark harness utilities - cmake/ (29 files): CMake presets and build helpers - cudax/ (794 files): Experimental CUDA extensions - AGENTS.md: NVIDIA's official AI agent instructions for CCCL - CMakePresets.json: Standardized build configurations - cccl-version.json: Version tracking Also added CCCL_ASSET_MAP.md mapping all 4295 CCCL files to competition value and PRD items. cccl_upstream now covers 100% of competition-critical assets: - 27 tuning headers (SM80/90/100 benchmark data) - 32 dispatch headers (algorithm implementations) - 60 Thrust examples (correctness verification) - 217 CUB Catch2 tests (regression matrix) - 153 CUB benchmarks (parameter space search) - 18 CUB examples (API verification) - 27 test helpers + benchmark harness - 794 cudax experimental extensions
This commit is contained in:
muh-bot
100
cccl_upstream/cudax/test/stf/stackable/composite_conditional.cu
Normal file
100
cccl_upstream/cudax/test/stf/stackable/composite_conditional.cu
Normal file
@@ -0,0 +1,100 @@
|
||||
//===----------------------------------------------------------------------===//
|
||||
//
|
||||
// Part of CUDASTF in CUDA C++ Core Libraries,
|
||||
// under the Apache License v2.0 with LLVM Exceptions.
|
||||
// See https://llvm.org/LICENSE.txt for license information.
|
||||
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
||||
// SPDX-FileCopyrightText: Copyright (c) 2026 NVIDIA CORPORATION & AFFILIATES.
|
||||
//
|
||||
//===----------------------------------------------------------------------===//
|
||||
|
||||
/**
|
||||
* @file
|
||||
* @brief Composite (localized) data places inside conditional graph scopes
|
||||
*
|
||||
* Regression test: localized_array allocations cached by a nested context
|
||||
* must survive the pop -- their teardown unmaps VMM backing with synchronous
|
||||
* driver calls, so destroying them with the nested context races the body
|
||||
* graph launched by the pop (cudaErrorIllegalAddress). The cache is handed
|
||||
* over to the parent context, gated on the body's completion events.
|
||||
*/
|
||||
|
||||
#include <cuda/experimental/stf.cuh>
|
||||
|
||||
#include <cstddef>
|
||||
#include <cstdio>
|
||||
|
||||
using namespace cuda::experimental::stf;
|
||||
using namespace cuda::experimental::places;
|
||||
|
||||
int main()
|
||||
{
|
||||
#if _CCCL_CTK_BELOW(12, 4) || defined(CUDASTF_DISABLE_CODE_GENERATION) || !defined(__CUDACC__)
|
||||
// Mirror the availability guard of while_graph_scope / repeat_graph_scope
|
||||
// in stackable_ctx_impl.cuh
|
||||
fprintf(stderr, "Waiving test: conditional graph scopes require CUDA 12.4+ and STF code generation.\n");
|
||||
return 0;
|
||||
#else
|
||||
stackable_ctx ctx;
|
||||
|
||||
// A 2-place grid on the current device: enough to build a composite data
|
||||
// place without requiring several devices or green context support.
|
||||
auto grid = exec_place::repeat(exec_place::current_device(), 2);
|
||||
|
||||
const size_t nx = 404, nz = 204, nv = 4;
|
||||
const size_t iters = 30;
|
||||
const auto part = make_partition(dim4(nx, nz, nv), partition_spec{whole, blocked<0>, whole}, grid.get_dims());
|
||||
const auto dp = make_composite_data_place(grid, part);
|
||||
|
||||
auto l = ctx.logical_data(shape_of<slice<double, 3>>(nx, nz, nv)).set_symbol("field");
|
||||
|
||||
ctx.parallel_for(part, grid, l.shape(), l.write(dp)).set_symbol("init")->*
|
||||
[] __device__(size_t i, size_t k, size_t v, auto s) {
|
||||
s(i, k, v) = 1.0;
|
||||
};
|
||||
|
||||
// While-form conditional scope driven by a device counter
|
||||
auto lcnt = ctx.logical_data(shape_of<scalar_view<size_t>>()).set_symbol("counter");
|
||||
ctx.parallel_for(box(1), lcnt.write()).set_symbol("init_counter")->*[iters] __device__(size_t, auto c) {
|
||||
*c = iters;
|
||||
};
|
||||
|
||||
{
|
||||
auto wg = ctx.while_graph_scope();
|
||||
ctx.parallel_for(part, grid, l.shape(), l.rw(dp)).set_symbol("body")->*
|
||||
[] __device__(size_t i, size_t k, size_t v, auto s) {
|
||||
s(i, k, v) += 1.0;
|
||||
};
|
||||
wg.update_cond(lcnt.rw())->*[] __device__(auto c) {
|
||||
(*c)--;
|
||||
return (*c > 0);
|
||||
};
|
||||
}
|
||||
|
||||
// Fixed-count form on the same composite field (also exercises reuse of
|
||||
// the cached localized_array imported into the parent by the first pop)
|
||||
{
|
||||
auto rg = ctx.repeat_graph_scope(iters);
|
||||
ctx.parallel_for(part, grid, l.shape(), l.rw(dp)).set_symbol("body2")->*
|
||||
[] __device__(size_t i, size_t k, size_t v, auto s) {
|
||||
s(i, k, v) += 1.0;
|
||||
};
|
||||
}
|
||||
|
||||
ctx.host_launch(l.read()).set_symbol("check")->*[&](auto s) {
|
||||
for (size_t v = 0; v < nv; v++)
|
||||
{
|
||||
for (size_t k = 0; k < nz; k++)
|
||||
{
|
||||
for (size_t i = 0; i < nx; i++)
|
||||
{
|
||||
EXPECT(s(i, k, v) == 1.0 + 2.0 * (double) iters);
|
||||
}
|
||||
}
|
||||
}
|
||||
};
|
||||
|
||||
ctx.finalize();
|
||||
return 0;
|
||||
#endif
|
||||
}
|
||||
177
cccl_upstream/cudax/test/stf/stackable/graph_scope_test.cu
Normal file
177
cccl_upstream/cudax/test/stf/stackable/graph_scope_test.cu
Normal file
@@ -0,0 +1,177 @@
|
||||
//===----------------------------------------------------------------------===//
|
||||
//
|
||||
// Part of CUDASTF in CUDA C++ Core Libraries,
|
||||
// under the Apache License v2.0 with LLVM Exceptions.
|
||||
// See https://llvm.org/LICENSE.txt for license information.
|
||||
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
||||
// SPDX-FileCopyrightText: Copyright (c) 2022-2025 NVIDIA CORPORATION & AFFILIATES.
|
||||
//
|
||||
//===----------------------------------------------------------------------===//
|
||||
|
||||
/**
|
||||
* @file
|
||||
* @brief Test for graph_scope RAII functionality in stackable_ctx
|
||||
*
|
||||
* This test demonstrates and validates the graph_scope RAII wrapper
|
||||
* for automatic push/pop management in nested contexts.
|
||||
*/
|
||||
|
||||
#include <cuda/experimental/stf.cuh>
|
||||
|
||||
using namespace cuda::experimental::stf;
|
||||
|
||||
int main()
|
||||
{
|
||||
stackable_ctx ctx;
|
||||
|
||||
int input[1024];
|
||||
for (size_t i = 0; i < 1024; i++)
|
||||
{
|
||||
input[i] = static_cast<int>(i);
|
||||
}
|
||||
|
||||
auto data = ctx.logical_data(input).set_symbol("data");
|
||||
|
||||
// Test 1: Direct constructor style (lock_guard style) - most idiomatic
|
||||
{
|
||||
stackable_ctx::graph_scope_guard scope{ctx}; // push() called here
|
||||
|
||||
auto temp = ctx.logical_data(data.shape()).set_symbol("temp");
|
||||
|
||||
ctx.parallel_for(temp.shape(), temp.write(), data.read())->*[] __device__(size_t i, auto temp, auto data) {
|
||||
temp(i) = data(i) * 2;
|
||||
};
|
||||
|
||||
ctx.parallel_for(data.shape(), data.write(), temp.read())->*[] __device__(size_t i, auto data, auto temp) {
|
||||
data(i) = temp(i) + 1;
|
||||
};
|
||||
|
||||
// pop() called automatically when scope goes out of scope
|
||||
}
|
||||
|
||||
// Test 2: Factory method style (convenience)
|
||||
{
|
||||
auto scope = ctx.graph_scope(); // push() called here
|
||||
|
||||
auto temp = ctx.logical_data(data.shape()).set_symbol("temp2");
|
||||
|
||||
ctx.parallel_for(temp.shape(), temp.write(), data.read())->*[] __device__(size_t i, auto temp, auto data) {
|
||||
temp(i) = data(i) * 3;
|
||||
};
|
||||
|
||||
ctx.parallel_for(data.shape(), data.write(), temp.read())->*[] __device__(size_t i, auto data, auto temp) {
|
||||
data(i) = temp(i);
|
||||
};
|
||||
|
||||
// pop() called automatically when scope goes out of scope
|
||||
}
|
||||
|
||||
// Test 3: Nested scopes with direct constructor style
|
||||
{
|
||||
stackable_ctx::graph_scope_guard outer_scope{ctx}; // outer push
|
||||
|
||||
auto intermediate = ctx.logical_data(data.shape()).set_symbol("intermediate");
|
||||
|
||||
ctx.parallel_for(intermediate.shape(), intermediate.write(), data.read())
|
||||
->*[] __device__(size_t i, auto inter, auto data) {
|
||||
inter(i) = data(i) / 2;
|
||||
};
|
||||
|
||||
{
|
||||
stackable_ctx::graph_scope_guard inner_scope{ctx}; // inner push (nested)
|
||||
|
||||
auto temp = ctx.logical_data(data.shape()).set_symbol("nested_temp");
|
||||
|
||||
ctx.parallel_for(temp.shape(), temp.write(), intermediate.read())->*[] __device__(size_t i, auto temp, auto inter) {
|
||||
temp(i) = inter(i) + 10;
|
||||
};
|
||||
|
||||
ctx.parallel_for(data.shape(), data.write(), temp.read())->*[] __device__(size_t i, auto data, auto temp) {
|
||||
data(i) = temp(i);
|
||||
};
|
||||
|
||||
// inner pop() called automatically here
|
||||
}
|
||||
|
||||
// outer pop() called automatically here
|
||||
}
|
||||
|
||||
// Test 4: Iterative pattern (like stackable2.cu)
|
||||
for (int iter = 0; iter < 3; iter++)
|
||||
{
|
||||
stackable_ctx::graph_scope_guard iteration{ctx}; // New scope each iteration
|
||||
|
||||
auto temp = ctx.logical_data(data.shape()).set_symbol("iter_temp");
|
||||
|
||||
// tmp = data
|
||||
ctx.parallel_for(temp.shape(), temp.write(), data.read())->*[] __device__(size_t i, auto temp, auto data) {
|
||||
temp(i) = data(i);
|
||||
};
|
||||
|
||||
// data++
|
||||
ctx.parallel_for(data.shape(), data.rw())->*[] __device__(size_t i, auto data) {
|
||||
data(i) += 1;
|
||||
};
|
||||
|
||||
// temp *= 2
|
||||
ctx.parallel_for(temp.shape(), temp.rw())->*[] __device__(size_t i, auto temp) {
|
||||
temp(i) *= 2;
|
||||
};
|
||||
|
||||
// data += temp
|
||||
ctx.parallel_for(data.shape(), temp.read(), data.rw())->*[] __device__(size_t i, auto temp, auto data) {
|
||||
data(i) += temp(i);
|
||||
};
|
||||
|
||||
// pop() called automatically at end of iteration
|
||||
}
|
||||
|
||||
// Test 5: Mixed usage styles
|
||||
{
|
||||
// Outer scope using direct constructor
|
||||
stackable_ctx::graph_scope_guard outer{ctx};
|
||||
|
||||
auto temp1 = ctx.logical_data(data.shape()).set_symbol("temp1");
|
||||
|
||||
{
|
||||
// Inner scope using factory method
|
||||
auto inner = ctx.graph_scope();
|
||||
|
||||
auto temp2 = ctx.logical_data(data.shape()).set_symbol("temp2");
|
||||
|
||||
ctx.parallel_for(temp2.shape(), temp2.write(), data.read())->*[] __device__(size_t i, auto temp2, auto data) {
|
||||
temp2(i) = data(i) + 5;
|
||||
};
|
||||
|
||||
ctx.parallel_for(temp1.shape(), temp1.write(), temp2.read())->*[] __device__(size_t i, auto temp1, auto temp2) {
|
||||
temp1(i) = temp2(i) * 2;
|
||||
};
|
||||
|
||||
// inner pop() automatically
|
||||
}
|
||||
|
||||
ctx.parallel_for(data.shape(), data.write(), temp1.read())->*[] __device__(size_t i, auto data, auto temp1) {
|
||||
data(i) = temp1(i);
|
||||
};
|
||||
|
||||
// outer pop() automatically
|
||||
}
|
||||
|
||||
ctx.finalize();
|
||||
|
||||
for (size_t i = 0; i < 1024; i++)
|
||||
{
|
||||
int expected = static_cast<int>(i);
|
||||
expected = expected * 2 + 1;
|
||||
expected = expected * 3;
|
||||
expected = expected / 2 + 10;
|
||||
for (int iter = 0; iter < 3; iter++)
|
||||
{
|
||||
expected = 3 * expected + 1;
|
||||
}
|
||||
expected = (expected + 5) * 2;
|
||||
EXPECT(input[i] == expected);
|
||||
}
|
||||
|
||||
return 0;
|
||||
}
|
||||
Reference in New Issue
Block a user