[CCCL] Add missing CCCL components: c2h, nvbench_helper, cmake, cudax, AGENTS.md

Added 863 files from NVIDIA/cccl sparse checkout:
- c2h/ (27 files): Catch2 test helpers — generators, validators, runner
- nvbench_helper/ (10 files): Benchmark harness utilities
- cmake/ (29 files): CMake presets and build helpers
- cudax/ (794 files): Experimental CUDA extensions
- AGENTS.md: NVIDIA's official AI agent instructions for CCCL
- CMakePresets.json: Standardized build configurations
- cccl-version.json: Version tracking

Also added CCCL_ASSET_MAP.md mapping all 4295 CCCL files to
competition value and PRD items.

cccl_upstream now covers 100% of competition-critical assets:
- 27 tuning headers (SM80/90/100 benchmark data)
- 32 dispatch headers (algorithm implementations)
- 60 Thrust examples (correctness verification)
- 217 CUB Catch2 tests (regression matrix)
- 153 CUB benchmarks (parameter space search)
- 18 CUB examples (API verification)
- 27 test helpers + benchmark harness
- 794 cudax experimental extensions

cccl_upstream/cudax/test/stf/cpp/redundant_data.cu

@@ -0,0 +1,86 @@
+//===----------------------------------------------------------------------===//
+//
+// Part of CUDASTF in CUDA C++ Core Libraries,
+// under the Apache License v2.0 with LLVM Exceptions.
+// See https://llvm.org/LICENSE.txt for license information.
+// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
+// SPDX-FileCopyrightText: Copyright (c) 2022-2024 NVIDIA CORPORATION & AFFILIATES.
+//
+//===----------------------------------------------------------------------===//
+
+/**
+ * @file
+ * @brief Ensure we can use the same logical data multiple time in a task
+ */
+
+#include <cuda/experimental/__stf/graph/graph_ctx.cuh>
+#include <cuda/experimental/__stf/stream/stream_ctx.cuh>
+
+using namespace cuda::experimental::stf;
+
+template <typename T>
+__global__ void diff_cnt(int n, T* x, T* y, int* delta)
+{
+  int tid      = blockIdx.x * blockDim.x + threadIdx.x;
+  int nthreads = gridDim.x * blockDim.x;
+
+  for (int ind = tid; ind < n; ind += nthreads)
+  {
+    if (y[ind] != x[ind])
+    {
+      atomicAdd(delta, 1);
+    }
+  }
+}
+
+template <typename Ctx, typename T>
+void compare_two_vectors(Ctx& ctx, logical_data<T>& a, logical_data<T>& b, int& delta)
+{
+  auto delta_cnt = ctx.logical_data(make_slice(&delta, 1));
+  const auto n   = a.shape().extent(0);
+
+  // Count the number of differences
+  ctx.task(a.read(), b.read(), delta_cnt.rw())->*[=](cudaStream_t stream, auto da, auto db, auto ddelta) {
+    diff_cnt<<<16, 128, 0, stream>>>(static_cast<int>(n), da.data_handle(), db.data_handle(), ddelta.data_handle());
+  };
+
+  // Read that value on the host
+  ctx.host_launch(delta_cnt.read())->*[&](auto /*unused*/) {};
+}
+
+static const size_t N = 12;
+
+template <class Ctx>
+void run(double (&X)[N], double (&Y)[N])
+{
+  Ctx ctx;
+  auto handle_X = ctx.logical_data(X);
+  auto handle_Y = ctx.logical_data(Y);
+
+  int ret1 = 0, ret2 = 0;
+
+  compare_two_vectors(ctx, handle_X, handle_Y, ret1);
+  compare_two_vectors(ctx, handle_X, handle_X, ret2);
+
+  ctx.finalize();
+
+  // After sync, we can inspect the returned values.
+  // First two vectors are different
+  assert(ret1 > 0);
+  // Other two vectors are equal
+  assert(ret2 == 0);
+}
+
+int main()
+{
+  double X[N], Y[N];
+
+  for (size_t ind = 0; ind < N; ind++)
+  {
+    X[ind] = 1.0 * ind;
+    Y[ind] = 2.0 * ind - 3.0;
+  }
+
+  run<stream_ctx>(X, Y);
+  run<graph_ctx>(X, Y);
+}