[CCCL] Add missing CCCL components: c2h, nvbench_helper, cmake, cudax, AGENTS.md

Added 863 files from NVIDIA/cccl sparse checkout:
- c2h/ (27 files): Catch2 test helpers — generators, validators, runner
- nvbench_helper/ (10 files): Benchmark harness utilities
- cmake/ (29 files): CMake presets and build helpers
- cudax/ (794 files): Experimental CUDA extensions
- AGENTS.md: NVIDIA's official AI agent instructions for CCCL
- CMakePresets.json: Standardized build configurations
- cccl-version.json: Version tracking

Also added CCCL_ASSET_MAP.md mapping all 4295 CCCL files to
competition value and PRD items.

cccl_upstream now covers 100% of competition-critical assets:
- 27 tuning headers (SM80/90/100 benchmark data)
- 32 dispatch headers (algorithm implementations)
- 60 Thrust examples (correctness verification)
- 217 CUB Catch2 tests (regression matrix)
- 153 CUB benchmarks (parameter space search)
- 18 CUB examples (API verification)
- 27 test helpers + benchmark harness
- 794 cudax experimental extensions

cccl_upstream/cudax/cmake/cudaxBuildCompilerTargets.cmake

@@ -0,0 +1,65 @@
+# Including this file defines the following targets:
+#
+# cudax.compiler_interface
+# - Interface target that includes all compiler settings for cudax tests, etc.
+
+cccl_get_cub()
+cccl_get_cudax()
+cccl_get_libcudacxx()
+cccl_get_thrust()
+
+set(cuda_compile_options)
+set(cxx_compile_options)
+set(cxx_compile_definitions)
+
+if ("MSVC" STREQUAL "${CMAKE_CXX_COMPILER_ID}")
+  # C4848: support for attribute 'msvc::no_unique_address' in C++17 and earlier is a vendor extension
+  append_option_if_available("/wd4848" cxx_compile_options)
+
+  # XXX Temporary hack for STF !
+  # C4267: conversion from 'meow' to 'purr', possible loss of data
+  append_option_if_available("/wd4267" cxx_compile_options)
+
+  # C4459 : declaration of 'identifier' hides global declaration
+  # We work around std::chrono::last which hides some internal "last" variable
+  append_option_if_available("/wd4459" cxx_compile_options)
+
+  # stf used getenv which is potentially unsafe but not in our context
+  list(APPEND cxx_compile_definitions "_CRT_SECURE_NO_WARNINGS")
+endif()
+
+if ("Clang" STREQUAL "${CMAKE_CXX_COMPILER_ID}")
+  # stf heavily uses host device lambdas which break on clang due to a warning about the implicitly
+  # deleted copy constructor
+  # TODO(bgruber): remove this when NVBug 4980157 is resolved
+  append_option_if_available("-Wno-deprecated-copy" cxx_compile_options)
+endif()
+
+list(APPEND cxx_compile_definitions CCCL_ENABLE_ASSERTIONS)
+
+# Some groups related experimental code is located directly in libcu++ and is guarded by
+# _CUDAX_ENABLE_GROUP_FEATURES_IN_LIBCUDACXX macro, otherwise it would lead to a lot of code duplication. We define this
+# macro for cudax code globally, to get access to get access to the code.
+#
+# Can be removed once groups are no longer experimental.
+list(APPEND cxx_compile_definitions _CUDAX_ENABLE_GROUP_FEATURES_IN_LIBCUDACXX)
+
+cccl_build_compiler_interface(
+  cudax.compiler_flags
+  "${cuda_compile_options}"
+  "${cxx_compile_options}"
+  "${cxx_compile_definitions}"
+)
+
+add_library(cudax.compiler_interface INTERFACE)
+target_link_libraries(
+  cudax.compiler_interface
+  INTERFACE
+    # order matters here, we need the cudax options to override the cccl options.
+    cccl.compiler_interface
+    cudax.compiler_flags
+    libcudacxx::libcudacxx
+    CUB::CUB
+    Thrust::Thrust
+    cudax::cudax
+)