[INFRA] Import NVIDIA/CCCL upstream as optimization reference library

CCCL (CUDA C++ Core Libraries) provides:
- CUB: device/block/warp-level GPU primitives (reduce, scan, sort, topk)
- Thrust: high-level parallel algorithms (transform_reduce, sort, scan)
- libcudacxx: CUDA C++ standard library (atomics, barriers, memory)
- cudax: experimental features (memory resources, allocators)
- Tuning policies: per-SM hardware-specific algorithm parameters

Competition optimization vectors mapped to CCCL:
- Output TPS (83% weight): warp_reduce, block_reduce, device_topk
- Input TPS (14% weight): device_scan, block_load, prefetch
- Cache TPS (3% weight): prefix caching strategy patterns
- Memory (0.9 util): pooled/cached/buddy allocators

Source: https://github.com/NVIDIA/cccl (shallow clone, HEAD only)
License: Apache-2.0

cccl_upstream/cudax/test/stf/stackable/graph_scope_test.cu

@@ -0,0 +1,177 @@
+//===----------------------------------------------------------------------===//
+//
+// Part of CUDASTF in CUDA C++ Core Libraries,
+// under the Apache License v2.0 with LLVM Exceptions.
+// See https://llvm.org/LICENSE.txt for license information.
+// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
+// SPDX-FileCopyrightText: Copyright (c) 2022-2025 NVIDIA CORPORATION & AFFILIATES.
+//
+//===----------------------------------------------------------------------===//
+
+/**
+ * @file
+ * @brief Test for graph_scope RAII functionality in stackable_ctx
+ *
+ * This test demonstrates and validates the graph_scope RAII wrapper
+ * for automatic push/pop management in nested contexts.
+ */
+
+#include <cuda/experimental/stf.cuh>
+
+using namespace cuda::experimental::stf;
+
+int main()
+{
+  stackable_ctx ctx;
+
+  int input[1024];
+  for (size_t i = 0; i < 1024; i++)
+  {
+    input[i] = static_cast<int>(i);
+  }
+
+  auto data = ctx.logical_data(input).set_symbol("data");
+
+  // Test 1: Direct constructor style (lock_guard style) - most idiomatic
+  {
+    stackable_ctx::graph_scope_guard scope{ctx}; // push() called here
+
+    auto temp = ctx.logical_data(data.shape()).set_symbol("temp");
+
+    ctx.parallel_for(temp.shape(), temp.write(), data.read())->*[] __device__(size_t i, auto temp, auto data) {
+      temp(i) = data(i) * 2;
+    };
+
+    ctx.parallel_for(data.shape(), data.write(), temp.read())->*[] __device__(size_t i, auto data, auto temp) {
+      data(i) = temp(i) + 1;
+    };
+
+    // pop() called automatically when scope goes out of scope
+  }
+
+  // Test 2: Factory method style (convenience)
+  {
+    auto scope = ctx.graph_scope(); // push() called here
+
+    auto temp = ctx.logical_data(data.shape()).set_symbol("temp2");
+
+    ctx.parallel_for(temp.shape(), temp.write(), data.read())->*[] __device__(size_t i, auto temp, auto data) {
+      temp(i) = data(i) * 3;
+    };
+
+    ctx.parallel_for(data.shape(), data.write(), temp.read())->*[] __device__(size_t i, auto data, auto temp) {
+      data(i) = temp(i);
+    };
+
+    // pop() called automatically when scope goes out of scope
+  }
+
+  // Test 3: Nested scopes with direct constructor style
+  {
+    stackable_ctx::graph_scope_guard outer_scope{ctx}; // outer push
+
+    auto intermediate = ctx.logical_data(data.shape()).set_symbol("intermediate");
+
+    ctx.parallel_for(intermediate.shape(), intermediate.write(), data.read())
+        ->*[] __device__(size_t i, auto inter, auto data) {
+              inter(i) = data(i) / 2;
+            };
+
+    {
+      stackable_ctx::graph_scope_guard inner_scope{ctx}; // inner push (nested)
+
+      auto temp = ctx.logical_data(data.shape()).set_symbol("nested_temp");
+
+      ctx.parallel_for(temp.shape(), temp.write(), intermediate.read())->*[] __device__(size_t i, auto temp, auto inter) {
+        temp(i) = inter(i) + 10;
+      };
+
+      ctx.parallel_for(data.shape(), data.write(), temp.read())->*[] __device__(size_t i, auto data, auto temp) {
+        data(i) = temp(i);
+      };
+
+      // inner pop() called automatically here
+    }
+
+    // outer pop() called automatically here
+  }
+
+  // Test 4: Iterative pattern (like stackable2.cu)
+  for (int iter = 0; iter < 3; iter++)
+  {
+    stackable_ctx::graph_scope_guard iteration{ctx}; // New scope each iteration
+
+    auto temp = ctx.logical_data(data.shape()).set_symbol("iter_temp");
+
+    // tmp = data
+    ctx.parallel_for(temp.shape(), temp.write(), data.read())->*[] __device__(size_t i, auto temp, auto data) {
+      temp(i) = data(i);
+    };
+
+    // data++
+    ctx.parallel_for(data.shape(), data.rw())->*[] __device__(size_t i, auto data) {
+      data(i) += 1;
+    };
+
+    // temp *= 2
+    ctx.parallel_for(temp.shape(), temp.rw())->*[] __device__(size_t i, auto temp) {
+      temp(i) *= 2;
+    };
+
+    // data += temp
+    ctx.parallel_for(data.shape(), temp.read(), data.rw())->*[] __device__(size_t i, auto temp, auto data) {
+      data(i) += temp(i);
+    };
+
+    // pop() called automatically at end of iteration
+  }
+
+  // Test 5: Mixed usage styles
+  {
+    // Outer scope using direct constructor
+    stackable_ctx::graph_scope_guard outer{ctx};
+
+    auto temp1 = ctx.logical_data(data.shape()).set_symbol("temp1");
+
+    {
+      // Inner scope using factory method
+      auto inner = ctx.graph_scope();
+
+      auto temp2 = ctx.logical_data(data.shape()).set_symbol("temp2");
+
+      ctx.parallel_for(temp2.shape(), temp2.write(), data.read())->*[] __device__(size_t i, auto temp2, auto data) {
+        temp2(i) = data(i) + 5;
+      };
+
+      ctx.parallel_for(temp1.shape(), temp1.write(), temp2.read())->*[] __device__(size_t i, auto temp1, auto temp2) {
+        temp1(i) = temp2(i) * 2;
+      };
+
+      // inner pop() automatically
+    }
+
+    ctx.parallel_for(data.shape(), data.write(), temp1.read())->*[] __device__(size_t i, auto data, auto temp1) {
+      data(i) = temp1(i);
+    };
+
+    // outer pop() automatically
+  }
+
+  ctx.finalize();
+
+  for (size_t i = 0; i < 1024; i++)
+  {
+    int expected = static_cast<int>(i);
+    expected     = expected * 2 + 1;
+    expected     = expected * 3;
+    expected     = expected / 2 + 10;
+    for (int iter = 0; iter < 3; iter++)
+    {
+      expected = 3 * expected + 1;
+    }
+    expected = (expected + 5) * 2;
+    EXPECT(input[i] == expected);
+  }
+
+  return 0;
+}