[INFRA] Import NVIDIA/CCCL upstream as optimization reference library

CCCL (CUDA C++ Core Libraries) provides:
- CUB: device/block/warp-level GPU primitives (reduce, scan, sort, topk)
- Thrust: high-level parallel algorithms (transform_reduce, sort, scan)
- libcudacxx: CUDA C++ standard library (atomics, barriers, memory)
- cudax: experimental features (memory resources, allocators)
- Tuning policies: per-SM hardware-specific algorithm parameters

Competition optimization vectors mapped to CCCL:
- Output TPS (83% weight): warp_reduce, block_reduce, device_topk
- Input TPS (14% weight): device_scan, block_load, prefetch
- Cache TPS (3% weight): prefix caching strategy patterns
- Memory (0.9 util): pooled/cached/buddy allocators

Source: https://github.com/NVIDIA/cccl (shallow clone, HEAD only)
License: Apache-2.0

cccl_upstream/cudax/test/stf/hashtable/fusion.cu

@@ -0,0 +1,64 @@
+//===----------------------------------------------------------------------===//
+//
+// Part of CUDASTF in CUDA C++ Core Libraries,
+// under the Apache License v2.0 with LLVM Exceptions.
+// See https://llvm.org/LICENSE.txt for license information.
+// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
+// SPDX-FileCopyrightText: Copyright (c) 2022-2024 NVIDIA CORPORATION & AFFILIATES.
+//
+//===----------------------------------------------------------------------===//
+
+#include <cuda/experimental/__stf/stream/interfaces/hashtable_linearprobing.cuh>
+#include <cuda/experimental/__stf/stream/stream_ctx.cuh>
+
+using namespace cuda::experimental::stf;
+
+// Iterate over every item in the hashtableA, and add them to B
+
+__global__ void gpu_merge_hashtable(hashtable A, const hashtable B)
+{
+  unsigned int threadid = blockIdx.x * blockDim.x + threadIdx.x;
+  while (threadid < reserved::kHashTableCapacity)
+  {
+    if (B.addr[threadid].key != reserved::kEmpty)
+    {
+      uint32_t value = B.addr[threadid].value;
+      if (value != reserved::kEmpty)
+      {
+        //    printf("INSERTING key %d value %d\n", pHashTableB[threadid].key, value);
+        A.insert(B.addr[threadid]);
+      }
+    }
+    threadid += blockDim.x * gridDim.x;
+  }
+}
+
+int main()
+{
+  stream_ctx ctx;
+
+  hashtable A;
+  A.insert(reserved::KeyValue(107, 4));
+  A.insert(reserved::KeyValue(108, 6));
+
+  hashtable B;
+  B.insert(reserved::KeyValue(7, 14));
+  B.insert(reserved::KeyValue(8, 16));
+
+  auto lA = ctx.logical_data(A);
+  auto lB = ctx.logical_data(B);
+
+  ctx.task(lA.rw(), lB.read())->*[](auto stream, auto hA, auto hB) {
+    gpu_merge_hashtable<<<32, 128, 0, stream>>>(hA, hB);
+    cuda_safe_call(cudaGetLastError());
+  };
+
+  ctx.host_launch(lA.read())->*[](auto hA) {
+    EXPECT(hA.get(107) == 4);
+    EXPECT(hA.get(108) == 6);
+    EXPECT(hA.get(7) == 14);
+    EXPECT(hA.get(8) == 16);
+  };
+
+  ctx.finalize();
+}

cccl_upstream/cudax/test/stf/hashtable/fusion_reduction.cu

@@ -0,0 +1,122 @@
+//===----------------------------------------------------------------------===//
+//
+// Part of CUDASTF in CUDA C++ Core Libraries,
+// under the Apache License v2.0 with LLVM Exceptions.
+// See https://llvm.org/LICENSE.txt for license information.
+// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
+// SPDX-FileCopyrightText: Copyright (c) 2022-2024 NVIDIA CORPORATION & AFFILIATES.
+//
+//===----------------------------------------------------------------------===//
+
+#include <cuda/experimental/__stf/stream/interfaces/hashtable_linearprobing.cuh>
+#include <cuda/experimental/__stf/stream/reduction.cuh>
+#include <cuda/experimental/__stf/stream/stream_ctx.cuh>
+
+using namespace cuda::experimental::stf;
+
+__global__ void gpu_merge_hashtable(hashtable A, const hashtable B)
+{
+  unsigned int threadid = blockIdx.x * blockDim.x + threadIdx.x;
+  while (threadid < B.get_capacity())
+  {
+    if (B.addr[threadid].key != reserved::kEmpty)
+    {
+      uint32_t value = B.addr[threadid].value;
+      if (value != reserved::kEmpty)
+      {
+        //    printf("INSERTING key %d value %d\n", pHashTableB[threadid].key, value);
+        A.insert(B.addr[threadid]);
+      }
+    }
+    threadid += blockDim.x * gridDim.x;
+  }
+}
+
+void cpu_merge_hashtable(hashtable A, const hashtable B)
+{
+  for (unsigned int i = 0; i < B.get_capacity(); i++)
+  {
+    if (B.addr[i].key != reserved::kEmpty)
+    {
+      uint32_t value = B.addr[i].value;
+      if (value != reserved::kEmpty)
+      {
+        //    printf("INSERTING key %d value %d\n", pHashTableB[threadid].key, value);
+        A.insert(B.addr[i]);
+      }
+    }
+  }
+}
+
+class hashtable_fusion_t : public stream_reduction_operator<hashtable>
+{
+  void op(const hashtable& in, hashtable& inout, const exec_place& e, cudaStream_t s) override
+  {
+    if (e.affine_data_place().is_host())
+    {
+      cuda_safe_call(cudaStreamSynchronize(s)); // TODO use a callback
+      cpu_merge_hashtable(inout, in);
+    }
+    else
+    {
+      gpu_merge_hashtable<<<32, 32, 0, s>>>(inout, in);
+    }
+  }
+
+  void init_op(hashtable& /*unused*/, const exec_place& /*unused*/, cudaStream_t /*unused*/) override
+  {
+    // This init operator is a no-op because hashtables are already
+    // initialized as empty tables
+  }
+};
+
+// A kernel to fill the hashtable with some fictitious values
+__global__ void fill_table(size_t dev_id, size_t cnt, hashtable h)
+{
+  unsigned int threadid = blockIdx.x * blockDim.x + threadIdx.x;
+  unsigned int nthreads = blockDim.x * gridDim.x;
+
+  for (unsigned int i = threadid; i < cnt; i += nthreads)
+  {
+    uint32_t key   = dev_id * 1000 + i;
+    uint32_t value = 2 * i;
+
+    reserved::KeyValue kvs(key, value);
+    h.insert(kvs);
+  }
+}
+
+int main()
+{
+  stream_ctx ctx;
+
+  // Explicit capacity of 2048 entries
+  hashtable refh(2048);
+  auto h_handle = ctx.logical_data(refh);
+
+  auto fusion_op = std::make_shared<hashtable_fusion_t>();
+
+  for (size_t dev_id = 0; dev_id < 4; dev_id++)
+  {
+    ctx.task(h_handle.relaxed(fusion_op))->*[&](auto stream, auto h) {
+      EXPECT(h.get_capacity() == 2048);
+      fill_table<<<32, 32, 0, stream>>>(dev_id, 10, h);
+    };
+  }
+
+  ctx.host_launch(h_handle.read())->*[&](auto h) {
+    // Check that the table contains all values
+    for (size_t dev_id = 0; dev_id < 4; dev_id++)
+    {
+      for (unsigned i = 0; i < 10; i++)
+      {
+        uint32_t key   = static_cast<uint32_t>(dev_id * 1000 + i);
+        uint32_t value = 2 * i;
+
+        EXPECT(h.get(key) == value);
+      }
+    }
+  };
+
+  ctx.finalize();
+}

cccl_upstream/cudax/test/stf/hashtable/parallel_for.cu

@@ -0,0 +1,38 @@
+//===----------------------------------------------------------------------===//
+//
+// Part of CUDASTF in CUDA C++ Core Libraries,
+// under the Apache License v2.0 with LLVM Exceptions.
+// See https://llvm.org/LICENSE.txt for license information.
+// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
+// SPDX-FileCopyrightText: Copyright (c) 2022-2024 NVIDIA CORPORATION & AFFILIATES.
+//
+//===----------------------------------------------------------------------===//
+
+#include <cuda/experimental/__stf/stream/interfaces/hashtable_linearprobing.cuh>
+#include <cuda/experimental/__stf/stream/stream_ctx.cuh>
+#include <cuda/experimental/__stf/utility/dimensions.cuh>
+
+using namespace cuda::experimental::stf;
+
+int main()
+{
+  stream_ctx ctx;
+
+  // This constructor automatically initializes an empty hashtable on the host
+  hashtable h;
+  auto lh = ctx.logical_data(h);
+
+  ctx.parallel_for(box(16), lh.rw())->*[] _CCCL_DEVICE(size_t i, auto h) {
+    uint32_t key   = 10 * i;
+    uint32_t value = 17 + i * 14;
+    h.insert(key, value);
+  };
+
+  ctx.finalize();
+
+  // Thanks to the write-back mechanism on lh, h has been updated
+  for (size_t i = 0; i < 16; i++)
+  {
+    assert(h.get(i * 10) == 17 + i * 14);
+  }
+}

cccl_upstream/cudax/test/stf/hashtable/parallel_for_shape.cu

@@ -0,0 +1,39 @@
+//===----------------------------------------------------------------------===//
+//
+// Part of CUDASTF in CUDA C++ Core Libraries,
+// under the Apache License v2.0 with LLVM Exceptions.
+// See https://llvm.org/LICENSE.txt for license information.
+// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
+// SPDX-FileCopyrightText: Copyright (c) 2022-2024 NVIDIA CORPORATION & AFFILIATES.
+//
+//===----------------------------------------------------------------------===//
+
+#include <cuda/experimental/__stf/stream/interfaces/hashtable_linearprobing.cuh>
+#include <cuda/experimental/__stf/stream/stream_ctx.cuh>
+#include <cuda/experimental/__stf/utility/dimensions.cuh>
+
+using namespace cuda::experimental::stf;
+
+int main()
+{
+  stream_ctx ctx;
+
+  // Create a logical data from a shape of hashtable
+  auto lh = ctx.logical_data(shape_of<hashtable>());
+
+  // A write() access is needed because we initialized lh from a shape, so there is no reference copy
+  ctx.parallel_for(box(16), lh.write())->*[] _CCCL_DEVICE(size_t i, auto h) {
+    uint32_t key   = 10 * i;
+    uint32_t value = 17 + i * 14;
+    h.insert(key, value);
+  };
+
+  ctx.host_launch(lh.rw())->*[](auto h) {
+    for (int i = 0; i < 16; i++)
+    {
+      EXPECT(h.get(i * 10) == 17 + i * 14);
+    }
+  };
+
+  ctx.finalize();
+}

cccl_upstream/cudax/test/stf/hashtable/test.cu

@@ -0,0 +1,65 @@
+//===----------------------------------------------------------------------===//
+//
+// Part of CUDASTF in CUDA C++ Core Libraries,
+// under the Apache License v2.0 with LLVM Exceptions.
+// See https://llvm.org/LICENSE.txt for license information.
+// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
+// SPDX-FileCopyrightText: Copyright (c) 2022-2024 NVIDIA CORPORATION & AFFILIATES.
+//
+//===----------------------------------------------------------------------===//
+
+#include <cuda/experimental/__stf/stream/interfaces/hashtable_linearprobing.cuh>
+#include <cuda/experimental/__stf/stream/stream_ctx.cuh>
+
+using namespace cuda::experimental::stf;
+
+// Insert the key/values in kvs into the hashtable
+__global__ void gpu_hashtable_insert_kernel(hashtable h, const reserved::KeyValue* kvs, unsigned int numkvs)
+{
+  unsigned int threadid = blockIdx.x * blockDim.x + threadIdx.x;
+  if (threadid < numkvs)
+  {
+    h.insert(kvs[threadid]);
+  }
+}
+
+void gpu_hashtable_insert(hashtable d_h, const reserved::KeyValue* device_kvs, unsigned int num_kvs, cudaStream_t stream)
+{
+  // Have CUDA calculate the thread block size
+  const auto occ_res  = reserved::compute_occupancy(gpu_hashtable_insert_kernel);
+  int threadblocksize = occ_res.block_size;
+  int gridsize        = ((uint32_t) num_kvs + threadblocksize - 1) / threadblocksize;
+
+  // Insert all the keys into the hash table
+  gpu_hashtable_insert_kernel<<<gridsize, threadblocksize, 0, stream>>>(d_h, device_kvs, (uint32_t) num_kvs);
+}
+
+int main()
+{
+  stream_ctx ctx;
+
+  // This constructor automatically initializes an empty hashtable on the host
+  hashtable h;
+  auto lh = ctx.logical_data(h);
+
+  // Create an array of values on the host
+  reserved::KeyValue kvs_array[16];
+  for (uint32_t i = 0; i < 16; i++)
+  {
+    kvs_array[i].key   = i * 10;
+    kvs_array[i].value = 17 + i * 14;
+  }
+  auto h_kvs_array = ctx.logical_data(make_slice(&kvs_array[0], 16));
+
+  ctx.task(lh.rw(), h_kvs_array.read())->*[](auto stream, auto h, auto a) {
+    gpu_hashtable_insert(h, a.data_handle(), static_cast<uint32_t>(a.extent(0)), stream);
+  };
+
+  ctx.finalize();
+
+  // Thanks to the write-back mechanism on lh, h has been updated
+  for (size_t i = 0; i < 16; i++)
+  {
+    assert(h.get(i * 10) == 17 + i * 14);
+  }
+}