[INFRA] Import NVIDIA/CCCL upstream as optimization reference library

CCCL (CUDA C++ Core Libraries) provides:
- CUB: device/block/warp-level GPU primitives (reduce, scan, sort, topk)
- Thrust: high-level parallel algorithms (transform_reduce, sort, scan)
- libcudacxx: CUDA C++ standard library (atomics, barriers, memory)
- cudax: experimental features (memory resources, allocators)
- Tuning policies: per-SM hardware-specific algorithm parameters

Competition optimization vectors mapped to CCCL:
- Output TPS (83% weight): warp_reduce, block_reduce, device_topk
- Input TPS (14% weight): device_scan, block_load, prefetch
- Cache TPS (3% weight): prefix caching strategy patterns
- Memory (0.9 util): pooled/cached/buddy allocators

Source: https://github.com/NVIDIA/cccl (shallow clone, HEAD only)
License: Apache-2.0

cccl_upstream/cudax/cmake/cudaxSTFConfigureTarget.cmake

@@ -0,0 +1,58 @@
+# Configures a target for the STF framework.
+function(cudax_stf_configure_target target_name)
+  set(options LINK_MATHLIBS)
+  set(oneValueArgs)
+  set(multiValueArgs)
+  cmake_parse_arguments(
+    CSCT
+    "${options}"
+    "${oneValueArgs}"
+    "${multiValueArgs}"
+    ${ARGN}
+  )
+
+  target_link_libraries(
+    ${target_name}
+    PRIVATE #
+      CUDA::cudart_static
+      CUDA::curand
+      CUDA::cuda_driver
+  )
+
+  if (cudax_ENABLE_CUDASTF_CODE_GENERATION)
+    target_compile_options(
+      ${target_name}
+      PRIVATE $<$<COMPILE_LANG_AND_ID:CUDA,NVIDIA>:--extended-lambda>
+    )
+  else()
+    target_compile_definitions(
+      ${target_name}
+      PRIVATE "CUDASTF_DISABLE_CODE_GENERATION"
+    )
+  endif()
+
+  target_compile_options(
+    ${target_name}
+    PRIVATE $<$<COMPILE_LANG_AND_ID:CUDA,NVIDIA>:--expt-relaxed-constexpr>
+  )
+
+  set_target_properties(
+    ${target_name}
+    PROPERTIES #
+      CUDA_RUNTIME_LIBRARY Static
+      CUDA_SEPARABLE_COMPILATION ON
+  )
+
+  if (CSCT_LINK_MATHLIBS)
+    target_link_libraries(
+      ${target_name}
+      PRIVATE #
+        CUDA::cublas
+        CUDA::cusolver
+    )
+  endif()
+
+  if (cudax_ENABLE_CUDASTF_BOUNDSCHECK)
+    target_compile_definitions(${target_name} PRIVATE "CUDASTF_BOUNDSCHECK")
+  endif()
+endfunction()